utils.tcl

Go to the documentation of this file.

##
# @brief Basic namespace for all Excentis Tcl extensions
#
namespace eval excentis {

##
# @brief This namespace holds all ByteBlower-related Tcl extensions, including the ByteBlower higher-layer Tcl API.
#
# These procedures are developed for higher-level usage of the ByteBlower API.
# They are mainly used to simplify running specific Test Scenarios similar to
# scenarios you know from the ByteBlower GUI.
#
namespace eval ByteBlower {

## \file
#
# @brief Utility module that provides <b>various ByteBlower helper methods</b> to ease Tcl development.
#
# It contains utilities such as bulk @apiref{ByteBlowerPort} generation.
#
# @copyright Excentis nv - www.excentis.com
#
package require excentis_basic

proc Generate.Ports.On.Switch { server trunk baseMac L3Config { ports all } } {

    # Method which will generate a ByteBlowerPort on each port of the trunking
    # interface of the server. The ports will have a different mac address,
    # starting with the provided base mac address. The same holds for the Layer 3 protocol, which
    # can use DHCP as as an alternative.
    # @param server ByteBlowerServer which will be used for the ByteBlowerPorts
    # @param trunk Interface nr of the trunk. E.g. 1
    # @param baseMac Start mac address for the ByteBlower ports.
    # @param L3Config which has the following format : L3Protocol { baseIp dhcp } { defaultGw 0.0.0.0 } { netmask 255.255.255.0 }
    # @param L3Protocol IPv4 or IPv6
    # @param baseIp Start IP adddress for the ByteBlower ports. If Dhcp is used,
    # just type dhcp or leave blank
    # @param defaultGw Default gateway, if dhcp is not used.
    # @param netmask Netmask is dhcp is not used.
    # @return list of generated ByteBlower ports.
    ##

    # Initialize L3Config
    set L3Protocol IPv4
    set baseIP dhcp
    set defaultGw 0.0.0.0
    set netmask 255.255.255.0
    set portList [ list ]
    # Parse the L3Config
    if { [llength $L3Config] > 0} {
        set L3Protocol [ lindex $L3Config 0 ]
        if { [llength $L3Config] > 1} {
            set baseIP [ lindex $L3Config 1 ]
        }
        if { [llength $L3Config] > 2} {
            set defaultGw [ lindex $L3Config 2 ]
        }
        if { [llength $L3Config] > 3} {
            set netmask [ lindex $L3Config 3 ]
        }
    }
    # We walk the interfaces on the server, and all interfaces which are on the requested
    # trunk will be used for generating a ByteBlowerPort.
    foreach interface [ $server Interfaces.Get ] {
        if { [string match trunk-$trunk-* $interface ]} {
            set portNr [ lindex [ split $interface - ] 2 ]
            if { [string equal $ports all] || [lsearch $ports $portNr ] != -1} {
                if { [ catch {
                            #         puts "Interface $portNr found"
                            # Ok, we found a matching interface.
                            set port [ $server Port.Create $interface ]
                            # Configure the port.
                            set baseMac [ ::excentis::basic::Mac.Increment $baseMac ]
                            [ $port Layer2.EthII.Set ] Mac.Set $baseMac
                            # Configure Layer 3.
                            if { [ string equal $L3Protocol IPv4 ] } {
                                set l3 [ $port Layer3.IPv4.Set ]
                                if { [string equal $baseIP dhcp ] } {
                                    [ $l3 Protocol.Dhcp.Get ] Perform
                                } else {
                                    set baseIP [ ::excentis::basic::IP.Increment $baseIP ]
                                    $l3 Ip.Set $baseIP
                                    $l3 Gateway.Set $defaultGw
                                    $l3 Netmask.Set $netmask
                                }
                            } else {
                                set l3 [ $port Layer3.IPv6.Set ]
                                if { [string equal $baseIP dhcp ] } {
                                    [ $l3 Protocol.Dhcp.Get ] Perform
                                } else {
                                    set baseIP [ ::excentis::basic::IPv6.Increment $baseIP ]
                                    $l3 Ip.Manual.Add $baseIP
                                    # The netmask is ignored.
                                    $l3 Gateway.Set $defaultGw
                                }
                            }
                            lappend portList $port
                        } errorObject ]} {
                    puts "Ignoring port $portNr"
                    lappend portList "null $errorObject"
                }
            } else {
                #       puts "Interface $portNr NOT found ( $interface )"
            }
        }
    }
    return $portList
}

proc Generate.Possible.Ports.On.Switch { server trunk baseMac L3Config { ports all } } {
    # Method which does the same @see Generate.Ports.On.Switch, but only on ports where no exception is thrown.
    #
    if {[string equal $ports all ]} {
        # Generate a start list.
        set interfaceList [ $server Interfaces.Get ]
        set porst [ list ]
        foreach interface $interfaceList {
            if { [string match trunk-$trunk-* $interface]} {
                lappend ports [ lindex [ split $interface - ] end ]
            }
        }
    }
    set result [ list ]
    while { [llength $ports ] > 0 && [ catch { set result [ Generate.Ports.On.Switch $server $trunk $baseMac $L3Config $ports ] } errorObject ]} {
        # Extract the port which caused the exception, remove it from the port list, and continue.
        set port [ lindex [ split $errorObject - ] end ]
        if { [string is digit $port]} {
            puts "Removing port $port ($errorObject)"
            set ports [ lremove $ports $port ]
        } else {
            error $errorObject
        }
    }
    return $result

}

}

}