checksum.tcl

Go to the documentation of this file.

##
# @brief Basic namespace for all Excentis Tcl extensions
#
namespace eval excentis {

##
# @brief Namespace for Excentis Tcl extensions for basic functions.
#
# This includes functionality such as:
# - Network frame generation
# - Address parsing and conversion
# - ...
#
namespace eval basic {

## \file
#
# @brief Utility module that provides functionality for <b>manually calculating various checksums</b> within both TCP and UDP frames.
#
# @copyright Excentis nv - www.excentis.com
#

proc Checksum.Udp.Calculate { frame {vlanCount 0} } {
    # calculates the udp checksum of a full ethernet frame <frame> (without ethernet crc tail) and with an ipv4 header.
    # the frame is provided as a list of bytes in 0xXX or 0xxx format 
    # the checksum is returned as a list of 2 bytes in 0xXX format (e.g. 0x1A 0x0C)
    #
    # @param frame The frame as a list of bytes in hex notation 0xXX
    # @param vlanCount The number of VLAN tags the frame contains
    #
    # @return The UDP checksum as a list of bytes in hex notation
    ##

    set temp $frame
    set frame [list]
    foreach {byte} $temp {
        lappend frame [format 0x%02X $byte]
    }

    #- Calculate start of L3 header
    set offSet [expr 14 + $vlanCount * 4]
    set frame [lrange $frame $offSet end]

    #- Grab the L3 and L4 header fields needed for pseudoheader
    set protocol [ lrange $frame 9 9 ]
    set sourceIp [ lrange $frame 12 15 ]
    set destIp [ lrange $frame 16 19 ]
    set sourcePort [ lrange $frame 20 21 ]
    set destPort [ lrange $frame 22 23 ]
    set udpLength [ lrange $frame 24 25 ]
    set udpData [ lrange $frame 28 end ]

    #- Create the checksum base from pseudoheader, data and optional padding
    set checksumCalcBytes [ list ]
    eval lappend checksumCalcBytes $sourceIp $destIp "0x00" $protocol $udpLength $sourcePort $destPort $udpLength "0x00" "0x00" $udpData
    if { [ expr [llength $udpData ] % 2 ] != 0} {
        eval lappend checksumCalcBytes "0x00"
    }

    #- Return the checksum
    return [ ::excentis::basic::CheckSum.16 $checksumCalcBytes ]
}

#**************************************************************************************************

proc Checksum.Udpv6.Calculate { frame {vlanCount 0} } {
    # calculates the udp checksum of a full ethernet frame <frame> (without ethernet crc tail) and with an ipv6 header.
    # the frame is provided as a list of bytes in 0xXX format 
    # the checksum is returned as a list of 2 bytes in 0xXX format (e.g. 0x1A 0x0C)
    #
    # @param frame The frame as a list of bytes in hex notation
    # @param vlanCount The number of VLAN tags the frame contains
    #
    # @return The UDP checksum as a list of bytes in hex notation
    ##

    set temp $frame
    set frame [list]
    foreach {byte} $temp {
        lappend frame [format 0x%02X $byte]
    }

    #- Calculate start of L3 header
    set offSet [expr 14 + $vlanCount * 4]
    set frame [lrange $frame $offSet end]

    #- Grab the L3 and L4 header fields needed for pseudoheader
    set nextHeader [ lrange $frame 6 6 ]
    set sourceIp [ lrange $frame 8 23 ]
    set destIp [ lrange $frame 24 39 ]
    set sourcePort [ lrange $frame 40 41 ]
    set destPort [ lrange $frame 42 43 ]
    set udpLength [ lrange $frame 44 45 ]
    set udpData [ lrange $frame 48 end ]

    #- Create the checksum base from pseudoheader, data and optional padding
    set checksumCalcBytes [ list ]
    eval lappend checksumCalcBytes $sourceIp $destIp "0x00" "0x00" $udpLength "0x00" "0x00" "0x00" $nextHeader $sourcePort $destPort $udpLength "0x00" "0x00" $udpData
    if { [ expr [llength $udpData ] % 2 ] != 0} {
        eval lappend checksumCalcBytes "0x00"
    }

    #- Return the checksum
    return [ ::excentis::basic::CheckSum.16 $checksumCalcBytes ]
}

#**************************************************************************************************

proc Checksum.Tcp.Calculate { frame {vlanCount 0} } {
    # calculates the tcp checksum of a full ethernet frame <frame> (without ethernet crc tail) and with an ipv4 header.
    # the frame is provided as a list of bytes in 0xXX or 0xxx format 
    # the checksum is returned as a list of 2 bytes in 0xXX format (e.g. 0x1A 0x0C)
    #
    # @param frame The frame as a list of bytes in hex notation
    # @param vlanCount The number of VLAN tags the frame contains
    #
    # @return The TCP checksum as a list of bytes in hex notation
    ##

    set temp $frame
    set frame [list]
    foreach {byte} $temp {
        lappend frame [format 0x%02X $byte]
    }

    #- Calculate start of L3 header
    set offSet [expr 14 + $vlanCount * 4]
    set frame [lrange $frame $offSet end]

    #- Grab the L3 and L4 header fields needed for pseudoheader
    set tcpLength [Short.To.Hex [ expr 0x[Hex.To.String [ lrange $frame 2 3 ]] - 20 ]]
    set protocol [ lrange $frame 9 9 ]
    set sourceIp [ lrange $frame 12 15 ]
    set destIp [ lrange $frame 16 19 ]
    set sourcePort [ lrange $frame 20 21 ]
    set destPort [ lrange $frame 22 23 ]
    set seqNumber [ lrange $frame 24 27 ]
    set ackNumber [ lrange $frame 28 31 ]
    set stuff [ lrange $frame 32 33 ]
    set window [ lrange $frame 34 35 ]
    set urgPointer [ lrange $frame 38 39 ]
    set tcpData [ lrange $frame 40 end ]

    #- Create the checksum base from pseudoheader, data and optional padding
    set checksumCalcBytes [ list ]
    eval lappend checksumCalcBytes $sourceIp $destIp "0x00" $protocol $tcpLength $sourcePort $destPort $seqNumber $ackNumber $stuff $window "0x00" "0x00" $urgPointer $tcpData
    if { [ expr [llength $tcpData ] % 2 ] != 0} {
        eval lappend checksumCalcBytes "0x00"
    }

    #- Return the checksum
    return [ ::excentis::basic::CheckSum.16 $checksumCalcBytes ]
}

#**************************************************************************************************

proc Checksum.Tcpv6.Calculate { frame {vlanCount 0} } {
    # calculates the tcp checksum of a full ethernet frame <frame> (without ethernet crc tail) and with an ipv6 header.
    # the frame is provided as a list of bytes in 0xXX or 0xxx format 
    # the checksum is returned as a list of 2 bytes in 0xXX format (e.g. 0x1A 0x0C)
    #
    # @param frame The frame as a list of bytes in hex notation
    # @param vlanCount The number of VLAN tags the frame contains
    #
    # @return The TCP checksum as a list of bytes in hex notation
    ##

    set temp $frame
    set frame [list]
    foreach {byte} $temp {
        lappend frame [format 0x%02X $byte]
    }

    #- Calculate start of L3 header
    set offSet [expr 14 + $vlanCount * 4]
    set frame [lrange $frame $offSet end]

    #- Grab the L3 and L4 header fields needed for pseudoheader
    set tcpLength [ lrange $frame 4 5 ]
    set nextHeader [ lrange $frame 6 6 ]
    set sourceIp [ lrange $frame 8 23 ]
    set destIp [ lrange $frame 24 39 ]
    set sourcePort [ lrange $frame 40 41 ]
    set destPort [ lrange $frame 42 43 ]
    set seqNumber [ lrange $frame 44 47 ]
    set ackNumber [ lrange $frame 48 51 ]
    set stuff [ lrange $frame 52 53 ]
    set window [ lrange $frame 54 55 ]
    set urgPointer [ lrange $frame 58 59 ]
    set tcpData [ lrange $frame 60 end ]

    #- Create the checksum base from pseudoheader, data and optional padding
    set checksumCalcBytes [ list ]
    eval lappend checksumCalcBytes $sourceIp $destIp $tcpLength "0x00" "0x00" "0x00" $nextHeader $sourcePort $destPort $seqNumber $ackNumber $stuff $window "0x00" "0x00" $urgPointer $tcpData
    if { [ expr [llength $tcpData ] % 2 ] != 0} {
        eval lappend checksumCalcBytes "0x00"
    }

    #- Return the checksum
    return [ ::excentis::basic::CheckSum.16 $checksumCalcBytes ]
}

#**************************************************************************************************

proc Checksum.Ipv4.Calculate { frame {vlanCount 0} } {
    # calculates the ipv4 header of a full ethernet frame <frame> (without ethernet crc tail)
    # the frame is provided as a list of bytes in 0xXX format 
    # the checksum is returned as a list of 2 bytes in 0xXX format (e.g. 0x1A 0x0C)
    #
    # @param frame The frame as a list of bytes in hex notation
    # @param vlanCount The number of VLAN tags the frame contains
    #
    # @return The IPv4 header checksum as a list of bytes in hex notation
    ##
    set temp $frame
    set frame [list]
    foreach { byte } $temp {
        lappend frame [format 0x%02X $byte]
    }

    #- Calculate start of L3 header
    set offSet [expr 14 + $vlanCount * 4]
    set frame [lrange $frame $offSet end]

    #- Grab the L3 header fields (except the checksum bytes)
    set ihl [ expr [lindex $frame 0] & 0x0F ]
    set prechecksum [ lrange $frame 0 9 ]
    set postchecksum [ lrange $frame 12 [expr 4 * $ihl - 1] ]

    #- Return the checksum
    return [ ::excentis::basic::CheckSum.16 [join [list $prechecksum "0x00 0x00" $postchecksum]] ]
}

#**************************************************************************************************

}

}